[Nagiosplug-checkins] nagiosplug/m4 alloca.m4, NONE, 1.1 np_coreutils.m4, 1.5, 1.6

Ton Voon tonvoon at users.sourceforge.net
Tue Jul 4 11:47:46 CEST 2006


Update of /cvsroot/nagiosplug/nagiosplug/m4
In directory sc8-pr-cvs7.sourceforge.net:/tmp/cvs-serv25785/m4

Modified Files:
	np_coreutils.m4 
Added Files:
	alloca.m4 
Log Message:
Added alloca.h check and fixed locale.h, wchar.h (Ari Pollak - 1516578)


--- NEW FILE: alloca.m4 ---
# alloca.m4 serial 5
dnl Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_ALLOCA],
[
  dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
  AC_REQUIRE([AC_PROG_CPP])
  AC_REQUIRE([AC_PROG_EGREP])

  AC_REQUIRE([AC_FUNC_ALLOCA])
  if test $ac_cv_func_alloca_works = no; then
    gl_PREREQ_ALLOCA
  fi

  # Define an additional variable used in the Makefile substitution.
  if test $ac_cv_working_alloca_h = yes; then
    AC_EGREP_CPP([Need own alloca], [
#if defined __GNUC__ || defined _AIX || defined _MSC_VER
	Need own alloca
#endif
      ],
      [AC_DEFINE(HAVE_ALLOCA, 1,
	    [Define to 1 if you have `alloca' after including <alloca.h>,
	     a header that may be supplied by this distribution.])
       ALLOCA_H=alloca.h],
      [ALLOCA_H=])
  else
    ALLOCA_H=alloca.h
  fi
  AC_SUBST([ALLOCA_H])

  AC_DEFINE(HAVE_ALLOCA_H, 1,
    [Define HAVE_ALLOCA_H for backward compatibility with older code
     that includes <alloca.h> only if HAVE_ALLOCA_H is defined.])
])

# Prerequisites of lib/alloca.c.
# STACK_DIRECTION is already handled by AC_FUNC_ALLOCA.
AC_DEFUN([gl_PREREQ_ALLOCA], [:])

Index: np_coreutils.m4
===================================================================
RCS file: /cvsroot/nagiosplug/nagiosplug/m4/np_coreutils.m4,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -d -r1.5 -r1.6
--- np_coreutils.m4	3 Jul 2006 07:55:52 -0000	1.5
+++ np_coreutils.m4	4 Jul 2006 09:47:44 -0000	1.6
@@ -12,12 +12,15 @@
 [
   AC_REQUIRE([AM_STDBOOL_H])
   AC_REQUIRE([gl_C_STRTOLD])
-  AC_REQUIRE([gl_GETOPT])
-  AC_REQUIRE([gl_AFS])
   AC_REQUIRE([gl_EXITFAIL])
-  AC_REQUIRE([gl_XALLOC])
-  AC_REQUIRE([gl_MOUNTLIST])
   AC_REQUIRE([gl_FSUSAGE])
-  AC_REQUIRE([gl_FUNC_GLIBC_UNLOCKED_IO])
+  AC_REQUIRE([gl_FUNC_ALLOCA])
+  AC_REQUIRE([gl_GETOPT])
+  AC_REQUIRE([gl_MOUNTLIST])
   AC_REQUIRE([gl_REGEX])
+  AC_REQUIRE([gl_XALLOC])
+  AC_REQUIRE([gl_FUNC_GLIBC_UNLOCKED_IO])
+
+dnl This is in jm-macros.m4, which calls prereq.m4, and then calls this afterwards
+  AC_REQUIRE([gl_AFS])
 ])





More information about the Commits mailing list