[Nagiosplug-checkins] SF.net SVN: nagiosplug: [1939] nagiosplug/trunk

[tonvoon at users.sourceforge.net]

Revision: 1939
          http://nagiosplug.svn.sourceforge.net/nagiosplug/?rev=1939&view=rev
Author:   tonvoon
Date:     2008-03-10 17:37:13 -0700 (Mon, 10 Mar 2008)

Log Message:
-----------
Possible fix for HP-UX compile problems of regex_internal.c

Modified Paths:
--------------
    nagiosplug/trunk/configure.in

Added Paths:
-----------
    nagiosplug/trunk/gl/m4/mbstate_t.m4

Modified: nagiosplug/trunk/configure.in
===================================================================
--- nagiosplug/trunk/configure.in	2008-03-11 00:10:23 UTC (rev 1938)
+++ nagiosplug/trunk/configure.in	2008-03-11 00:37:13 UTC (rev 1939)
@@ -435,6 +435,7 @@
 AC_TYPE_PID_T
 AC_TYPE_SIZE_T
 AC_TYPE_SIGNAL
+AC_TYPE_MBSTATE_T
 
 AC_CACHE_CHECK([for va_copy],ac_cv_HAVE_VA_COPY,[
 AC_TRY_LINK([#include <stdarg.h>

Added: nagiosplug/trunk/gl/m4/mbstate_t.m4
===================================================================
--- nagiosplug/trunk/gl/m4/mbstate_t.m4	                        (rev 0)
+++ nagiosplug/trunk/gl/m4/mbstate_t.m4	2008-03-11 00:37:13 UTC (rev 1939)
@@ -0,0 +1,30 @@
+# mbstate_t.m4 serial 9
+dnl Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+# From Paul Eggert.
+
+# BeOS 5 has <wchar.h> but does not define mbstate_t,
+# so you can't declare an object of that type.
+# Check for this incompatibility with Standard C.
+
+# AC_TYPE_MBSTATE_T
+# -----------------
+AC_DEFUN([AC_TYPE_MBSTATE_T],
+  [AC_CACHE_CHECK([for mbstate_t], ac_cv_type_mbstate_t,
+     [AC_COMPILE_IFELSE(
+	[AC_LANG_PROGRAM(
+	   [AC_INCLUDES_DEFAULT
+#	    include <wchar.h>],
+	   [mbstate_t x; return sizeof x;])],
+	[ac_cv_type_mbstate_t=yes],
+	[ac_cv_type_mbstate_t=no])])
+   if test $ac_cv_type_mbstate_t = yes; then
+     AC_DEFINE([HAVE_MBSTATE_T], 1,
+	       [Define to 1 if <wchar.h> declares mbstate_t.])
+   else
+     AC_DEFINE([mbstate_t], int,
+	       [Define to a type if <wchar.h> does not define.])
+   fi])


This was sent by the SourceForge.net collaborative development platform, the world's largest Open Source development site.